Linux0.11操作系统（哈工大李治军老师）实验楼实验1-引导
Linux0.11操作系统（哈工大李治军老师）实验楼实验1-引导
Linux0.11操作系统（哈工大李治军老师）实验楼实验1-引导
实验源地址： https://www.lanqiao.cn/courses/115/learning/
1.完成bootsect.s屏幕输出功能
bootsect.s 能在屏幕上打印一段提示信息“XXX is booting…”，其中 XXX 是你给自己的操作系统起的名字，例如 LZJos、Sunix 等（可以上论坛上秀秀谁的 OS 名字最帅，也可以显示一个特色 logo，以表示自己操作系统的与众不同(.)
此处需要用到的中断：0x10，参考：0x10详解
1.读入光标位置，设置AH = 0x03，BH = 0x00，进入中断；
mov ah,#0x03
xor bh,bh
int 0x10
2.此处，bootsect.s必须以0xAA55结尾，占2KB大小，所以前面要设置成510KB
! msg1 处放置字符串
msg1:
! 换行 + 回车
.byte 13,10
.ascii "Hello OS world, my name is LZJ"
! 两对换行 + 回车
.byte 13,10,13,10
! boot_flag 必须在最后两个字节
.org 510
! 设置引导扇区标记 0xAA55
! 必须有它，才能引导
boot_flag:
.word 0xAA55
3.将字符串的长度赋值给cx;bx为0x10中断调用AH = 0x13时，设置字符串的属性；bp指向字符串的地址；然后设置段地址es；这时根据AH = 0x13，显示的数据是串地址ES:BP。
! 显示字符串 “Hello OS world, my name is ZXH”
! 要显示的字符串长度
mov cx,#36
mov bx,#0x0007
mov bp,#msg1
! es:bp 是显示字符串的地址
! 相比与 linux-0.11 中的代码，需要增加对 es 的处理，因为原代码中在输出之前已经处理了 es
mov ax,#0x07c0
mov es,ax
mov ax,#0x1301
int 0x10
4.设置死循环，使其停留在这里
inf_loop:
jmp inf_loop
下列为完整代码：
entry _start
_start:
mov ah,#0x03
xor bh,bh
int 0x10
mov cx,#36
mov bx,#0x0007
mov bp,#msg1
mov ax,#0x07c0
mov es,ax
mov ax,#0x1301
int 0x10
inf_loop:
jmp inf_loop
msg1:
.byte 13,10
.ascii "Hello OS world, my name is ZXH"
.byte 13,10,13,10
.org 510
boot_flag:
.word 0xAA55
5.编译，链接
as86 -0 -a -o bootsect.o bootsect.s
ld86 -0 -s -o bootsect bootsect.o
然后使用命令ls -l显示刚生成的文件属性
但是我们bootsect.s文件的大小必须占用一个磁盘扇区512KB，并且按照之前我们编写的文件，其大小应该正好是512KB，具体原因请参考实验楼李老师的说明。
6.我们需要用命令去掉文件头
dd bs=1 if=bootsect of=Image skip=32
关于指令dd，请参考：dd
7.运行
./run
2.改写setup.s的主要功能
2.1 bootsect.s 能完成 setup.s 的载入，并跳转到 setup.s 开始地址执行。而 setup.s 向屏幕输出一行"Now we are in SETUP"
此处需要用到的中断：0x10,0x13;有关0x13中断，参考此处：0x13
2.1.1 编写setup.s
同bootsect.s，只需将寄存器和字符串更改即可；
2.1.2 完成bootsect.s对setup.s的载入
在原bootsect.s中，就存在此功能，并且无需更改；
此处解释下为何setup.s的段地址是0x7ce0?
bootsect.s从ES = 0x7c00处开始读入，大小为512KB，后面开始运行setup.s，则，setup.s的段地址应该是ES : 512KB。
load_setup:
! 设置驱动器和磁头(drive 0, head 0): 软盘 0 磁头
mov dx,#0x0000
! 设置扇区号和磁道(sector 2, track 0): 0 磁头、0 磁道、2 扇区
mov cx,#0x0002
! 设置读入的内存地址：BOOTSEG+address = 512，偏移512字节
mov bx,#0x0200
! 设置读入的扇区个数(service 2, nr of sectors)，
! SETUPLEN是读入的扇区个数，Linux 0.11 设置的是 4，
! 我们不需要那么多，我们设置为 2（因此还需要添加变量 SETUPLEN=2）
mov ax,#0x0200+SETUPLEN
! 应用 0x13 号 BIOS 中断读入 2 个 setup.s扇区
int 0x13
! 读入成功，跳转到 ok_load_setup: ok - continue
jnc ok_load_setup
! 软驱、软盘有问题才会执行到这里。我们的镜像文件比它们可靠多了
mov dx,#0x0000
! 否则复位软驱 reset the diskette
mov ax,#0x0000
int 0x13
! 重新循环，再次尝试读取
jmp load_setup
ok_load_setup:
! 接下来要干什么？当然是跳到 setup 执行。
! 要注意：我们没有将 bootsect 移到 0x9000，因此跳转后的段地址应该是 0x7ce0
! 即我们要设置 SETUPSEG=0x07e0
2.1.3跳转到setup.s
要完成跳转，需要将bootsect.s之前设置的循环去掉，并jmpi到段地址SETUPSEG处
ok_load_setup:
jmpi 0,SETUPSEG
bootsect.s完整代码：
SETUPLEN=2
SETUPSEG=0x07e0
entry _start
_start:
mov ah,#0x03
xor bh,bh
int 0x10
mov cx,#36
mov bx,#0x0007
mov bp,#msg1
mov ax,#0x07c0
mov es,ax
mov ax,#0x1301
int 0x10
load_setup:
mov dx,#0x0000
mov cx,#0x0002
mov bx,#0x0200
mov ax,#0x0200+SETUPLEN
int 0x13
jnc ok_load_setup
mov dx,#0x0000
mov ax,#0x0000
int 0x13
jmp load_setup
ok_load_setup:
jmpi 0,SETUPSEG
msg1:
.byte 13,10
.ascii "Hello OS world, my name is LZJ"
.byte 13,10,13,10
.org 510
boot_flag:
.word 0xAA55
2.1.4 编译，链接
因为要对两个文件均编译，链接，所以采用Makefile的方式。
从oslab进入到linux-0.11目录下后，使用下述命令：
make BootImage
但是会报错，原因在于Makefile中执行了./tools/build.c。
build.c 从命令行参数得到 bootsect、setup 和 system 内核的文件名，将三者做简单的整理后一起写入 Image。其中 system 是第三个参数（argv[3]）。当 “make all” 或者 “makeall” 的时候，这个参数传过来的是正确的文件名，build.c 会打开它，将内容写入 Image。
而 “make BootImage” 时，传过来的是字符串 “none”。所以，改造 build.c 的思路就是当 argv[3] 是"none"的时候，只写 bootsect 和 setup，忽略所有与 system 有关的工作，或者在该写 system 的位置都写上 “0”。
打开Makefile
vim Makefile
修改build.c文件即可；
将~/linux-0.11/boot/中原本的所有bootsect和setup文件全部删掉
再将我们写的两个文件复制过来
再次./run运行
2.2 setup.s 能获取至少一个基本的硬件参数（如内存参数、显卡参数、硬盘参数等），将其存放在内存的特定地址，并输出到屏幕上
获取硬件参数放到内存的0x90000处。在原版的setup.s中，已经完成了光标位置、内存大小显存大小、显卡参数、第一和第二硬盘参数的保存。
2.2.1读取光标位置
mov [0],dx表示，在偏移地址0处写入光标位置；
在完整代码中，下面可看大，已经设置了基地址ds = 0x9000，所以完整写法应该是ds:[0]。
mov ah,#0x03
! 读入光标位置
xor bh,bh
! 调用 0x10 中断
int 0x10
! 将光标位置写入 0x90000.
mov [0],dx
2.2.2读取内存大小
此处所需中断：0x15
! 读入内存大小位置
mov ah,#0x88
int 0x15
mov [2],ax
2.2.3 读取磁盘参数表
有些硬件参数的获取要稍微复杂一些，如磁盘参数表。
在 PC 机中 BIOS 设定的中断向量表中 int 0x41 的中断向量位置(4*0x41 = 0x0000:0x0104)存放的并不是中断程序的地址，而是第一个硬盘的基本参数表。第二个硬盘的基本参数表入口地址存于 int 0x46 中断向量位置处。每个硬盘参数表有 16 个字节大小。
也就是说我们只要读取int 0x41的中断向量位置，就可以读取硬盘参数表。
| 位移 | 大小 | 说明 |
|---|---|---|
| 0x00 | 字 | 柱面数 |
| 0x02 | 字节 | 磁头数 |
| . | … | … |
| 0x0E | 字节 | 每磁道扇区数 |
| 0x0F | 字节 | 保留 |
每个中断向量表长4KB,我们要显示0x41的中断的地址，所以要用4 * 0x41。
movsb（点击链接）：是数据传送指令，将数据但从源地址DS : SI传到目的地址ES : DI。
此处即：将硬盘参数表从DS : SI处，传到了ES : DI处，即0x90004的位置。
! 从 0x41 处拷贝 16 个字节（磁盘参数表）
mov ax,#0x0000
mov ds,ax
lds si,[4*0x41]
mov ax,#INITSEG
mov es,ax
mov di,#0x0004
mov cx,#0x10
! 重复16次
rep
movsb
2.2.4获取光标位置
关于print_hex函数，参考2.3节。
! Cursor Position
mov ah,#0x03
xor bh,bh
int 0x10
mov cx,#18
mov bx,#0x0007
mov bp,#msg_cursor
mov ax,#0x1301
int 0x10
mov dx,[0]
call print_hex
2.2.5 获取内存大小并打印KB两个字
! Memory Size
mov ah,#0x03
xor bh,bh
int 0x10
mov cx,#14
mov bx,#0x0007
mov bp,#msg_memory
mov ax,#0x1301
int 0x10
mov dx,[2]
call print_hex
！打印KB两个字
mov ah,#0x03
xor bh,bh
int 0x10
mov cx,#2
mov bx,#0x0007
mov bp,#msg_kb
mov ax,#0x1301
int 0x10
2.2.6 打印参数
! Cyles
mov ah,#0x03
xor bh,bh
int 0x10
mov cx,#7
mov bx,#0x0007
mov bp,#msg_cyles
mov ax,#0x1301
int 0x10
mov dx,[4]
call print_hex
! Heads
mov ah,#0x03
xor bh,bh
int 0x10
mov cx,#8
mov bx,#0x0007
mov bp,#msg_heads
mov ax,#0x1301
int 0x10
mov dx,[6]
call print_hex
! Secotrs
mov ah,#0x03
xor bh,bh
int 0x10
mov cx,#10
mov bx,#0x0007
mov bp,#msg_sectors
mov ax,#0x1301
int 0x10
mov dx,[12]
call print_hex
2.3setup.s 不再加载 Linux 内核，保持上述信息显示在屏幕上即可
现在已经将硬件参数（只包括光标位置、内存大小和硬盘参数，其他硬件参数取出的方法基本相同，此处略去）取出来放在了 0x90000 处，接下来的工作是将这些参数显示在屏幕上。这些参数都是一些无符号整数，所以需要做的主要工作是用汇编程序在屏幕上将这些整数显示出来
以十六进制方式显示比较简单。这是因为十六进制与二进制有很好的对应关系（每 4 位二进制数和 1 位十六进制数存在一一对应关系），显示时只需将原二进制数每 4 位划成一组，按组求对应的 ASCII 码送显示器即可。
而ASCII 码与十六进制数字的对应关系为：0x30 ～ 0x39 对应数字 0 ～ 9，0x41 ～ 0x46 对应数字 a ～ f。从数字 9 到 a，其 ASCII 码间隔了 7h，这一点在转换时要特别注意。为使一个十六进制数能按高位到低位依次显示，实际编程中，需对 bx 中的数每次循环左移一组（4 位二进制），然后屏蔽掉当前高 12 位，对当前余下的 4 位（即 1 位十六进制数）求其 ASCII 码，要判断它是 0 ～ 9 还是 a ～ f，是前者则加 0x30 得对应的 ASCII 码，后者则要加 0x37 才行，最后送显示器输出。以上步骤重复 4 次，就可以完成 bx 中数以 4 位十六进制的形式显示出来。
关于ROL:ROL
代码解释参考注释。
! 以 16 进制方式打印栈顶的16位数
print_hex:
! 4 个十六进制数字
mov cx,#4
! 将(bp)所指的值放入 dx 中，如果 bp 是指向栈顶的话
mov dx,(bp)
print_digit:
! 循环以使低 4 比特用上 !! 取 dx 的高 4 比特移到低 4 比特处。
rol dx,#4
! ah = 请求的功能值，al = 半字节(4 个比特)掩码。
mov ax,#0xe0f
! 取 dl 的低 4 比特值。进行`与`的第四位比较，f 在二进制中是 1111，所以就是显示dl的值
and al,dl
! 给 al 数字加上十六进制 0x30
add al,#0x30
！参考上述关于ASCII的解释，0 ~ 9 对应 0x30 ~ 0x39,而a ~ f 对应0x41 ~ 0x46, 0x41 - 0x39 = 0x08,所以中间差了7h
！所以这里和0x3a比较，小于它的话，直接输出；
！所以这里功能即使判断是数字还是字母
cmp al,#0x3a
! 是一个不大于十的数字
jl outp
! 是a～f，要多加 7
add al,#0x07
outp:
int 0x10
loop print_digit
ret
! 这里用到了一个 loop 指令;
! 每次执行 loop 指令，cx 减 1，然后判断 cx 是否等于 0。
! 如果不为 0 则转移到 loop 指令后的标号处，实现循环；
! 如果为0顺序执行。
!
! 另外还有一个非常相似的指令：rep 指令，
! 每次执行 rep 指令，cx 减 1，然后判断 cx 是否等于 0。
！ 如果不为 0 则继续执行 rep 指令后的串操作指令，直到 cx 为 0，实现重复。
! 打印回车换行
print_nl:
! CR
mov ax,#0xe0d
int 0x10
! LF
mov al,#0xa
int 0x10
ret
完整代码
INITSEG = 0x9000
entry _start
_start:
! Print "NOW we are in SETUP"
mov ah,#0x03
xor bh,bh
int 0x10
mov cx,#25
mov bx,#0x0007
mov bp,#msg2
mov ax,cs
mov es,ax
mov ax,#0x1301
int 0x10
mov ax,cs
mov es,ax
! init ss:sp
mov ax,#INITSEG
mov ss,ax
mov sp,#0xFF00
! Get Params
mov ax,#INITSEG
mov ds,ax
mov ah,#0x03
xor bh,bh
int 0x10
mov [0],dx
mov ah,#0x88
int 0x15
mov [2],ax
mov ax,#0x0000
mov ds,ax
lds si,[4*0x41]
mov ax,#INITSEG
mov es,ax
mov di,#0x0004
mov cx,#0x10
rep
movsb
! Be Ready to Print
mov ax,cs
mov es,ax
mov ax,#INITSEG
mov ds,ax
! Cursor Position
mov ah,#0x03
xor bh,bh
int 0x10
mov cx,#18
mov bx,#0x0007
mov bp,#msg_cursor
mov ax,#0x1301
int 0x10
mov dx,[0]
call print_hex
! Memory Size
mov ah,#0x03
xor bh,bh
int 0x10
mov cx,#14
mov bx,#0x0007
mov bp,#msg_memory
mov ax,#0x1301
int 0x10
mov dx,[2]
call print_hex
! Add KB
mov ah,#0x03
xor bh,bh
int 0x10
mov cx,#2
mov bx,#0x0007
mov bp,#msg_kb
mov ax,#0x1301
int 0x10
! Cyles
mov ah,#0x03
xor bh,bh
int 0x10
mov cx,#7
mov bx,#0x0007
mov bp,#msg_cyles
mov ax,#0x1301
int 0x10
mov dx,[4]
call print_hex
! Heads
mov ah,#0x03
xor bh,bh
int 0x10
mov cx,#8
mov bx,#0x0007
mov bp,#msg_heads
mov ax,#0x1301
int 0x10
mov dx,[6]
call print_hex
! Secotrs
mov ah,#0x03
xor bh,bh
int 0x10
mov cx,#10
mov bx,#0x0007
mov bp,#msg_sectors
mov ax,#0x1301
int 0x10
mov dx,[12]
call print_hex
inf_loop:
jmp inf_loop
print_hex:
mov cx,#4
print_digit:
rol dx,#4
mov ax,#0xe0f
and al,dl
add al,#0x30
cmp al,#0x3a
jl outp
add al,#0x07
outp:
int 0x10
loop print_digit
ret
print_nl:
mov ax,#0xe0d ! CR
int 0x10
mov al,#0xa ! LF
int 0x10
ret
msg2:
.byte 13,10
.ascii "NOW we are in SETUP"
.byte 13,10,13,10
msg_cursor:
.byte 13,10
.ascii "Cursor position:"
msg_memory:
.byte 13,10
.ascii "Memory Size:"
msg_cyles:
.byte 13,10
.ascii "Cyls:"
msg_heads:
.byte 13,10
.ascii "Heads:"
msg_sectors:
.byte 13,10
.ascii "Sectors:"
msg_kb:
.ascii "KB"
.org 510
boot_flag:
.word 0xAA55
修改setup.s后，重复2.1.4编译链接的命令，运行./run.
更多推荐
8
0- 0
已为社区贡献1条内容
所有评论(0)